comment programma R 764 t.b.v. Van Vlissingen, MLP 170862 / 2054;
begin	real R, G, B, X, Y, Z, Wx, Vy, Wz, Wxs, Vys, Wzs, fdE; integer N, n;
	real procedure V (u); value u; real u;
	begin	real z;
		procedure newton;
		begin	real b, c;  b:= c:= .0008404;
			b:= z * b - .021009; c:= z * c + b;
			b:= z * b + .23951 ; c:= z * c + b;
			b:= z * b - .23111 ; c:= z * c + b;
			b:= z * b + 1.2219 ; c:= z * c + b;
			b:= z * b - u; z:= z - b / c
		end;
		z:= sqrt (u); newton; newton; newton; newton ; V:= z
	end V;

	NLCR; NLCR; NLCR; PRINTTEXT (" no.   fdE      x1       y1"); NLCR;
	N:= read; for n:= 1 step 1 until N do
	begin	NLCR; FIXT (3, 0, read); R:= read; G:= read; B:= read;
		X:= .78 * R + .20 * B; Y:= G; Z:= 1.18 * B;
		Vy:= V (G); Wx:= V (X / .98) - Vy; Wz:= V (B) - Vy;
		if n = 1 then begin Wxs:= Wx; Vys:= Vy; Wzs:= Wz end;
		fdE:= 40 * sqrt (.0529 * (Vy - Vys) ** 2 + (Wx - Wxs) ** 2 + .16 * (Wz - Wzs) ** 2);
		FIXT (1, 4, fdE); Z:= X + Y + Z; FIXT (1, 5, X / Z); FIXT (1, 5, Y / Z)
	end
end